/* import data */
PROC IMPORT OUT= WORK.pulse
DATAFILE= "D:\ECUconsultation\SASworkshop\pulserate.xls"
DBMS=EXCEL REPLACE;
RANGE="Sheet1$";
GETNAMES=YES;
MIXED=NO;
SCANTEXT=YES;
USEDATE=YES;
SCANTIME=YES;
RUN;
proc print data=pulse;
id ID;
run;
/* slides 9 */
proc sort data=pulse;
by Smoker;
run;
proc boxplot data = pulse;
plot Pulse1*Smoker;
label Pulse1 = 'First pulse measure'
Smoker = 'Smoking status';
run;
/* slides 10 */
proc univariate data=pulse noprint;
label Pulse1 = 'First pulse measure';
by smoker;
histogram pulse1 / midpoints =
52 62 72 82 92 102 112 122 132 142;
run;
/* slides 11 */
proc univariate data=pulse noprint;
label Pulse1 = 'First pulse measure';
by smoker;
var pulse1;
qqplot / normal(mu=est sigma=est);
run;
/* slides 12 */
proc means data=pulse;
label Pulse1 = 'First pulse measure';
class smoker;
var pulse1;
run;
/* slides 13 */
proc univariate data=pulse plot;
label Pulse1 = 'First pulse measure';
where smoker='No';
var pulse1;
run;
/* slides 14 */
proc ttest data=pulse;
class smoker;
var pulse1;
run;
/* slides 15 */
proc ttest data=pulse;
class gender;
var pulse1;
run;
proc ttest data=pulse;
class alcohol;
var pulse1;
run;
/* slides 16 */
proc sort data=pulse;
by ran;
run;
proc ttest data=pulse;
paired pulse1*pulse2;
by ran;
run;
/* slides 17 */
data pulse;
set pulse;
PulseDiff = Pulse2 - Pulse1;
run;
proc ttest data=pulse;
class ran;
var PulseDiff;
run;
/* slides 18 */
proc sort data=pulse;
by Exercise;
run;
proc boxplot data = pulse;
plot Pulse1*Exercise;
label Pulse1 = 'First pulse measure';
run;
/* slides 19 */
proc means data=pulse;
label Pulse1 = 'First pulse measure';
class exercise;
var pulse1;
run;
/* slides 20 - 21 */
proc glm data=pulse;
class exercise;
model pulse1 = exercise;
lsmeans exercise / pdiff ADJUST=TUKEY;
run;
/* slides 22 */
proc glm data=pulse;
class exercise;
model pulse1 = exercise;
lsmeans exercise / pdiff=control("Low") ADJUST=DUNNETT;
run;
/* slides 23 */
proc glm data=pulse;
class exercise;
model pulse1 = exercise;
contrast 'high vs. (low+moderate)/2' exercise 1 -0.5 -0.5;
estimate 'low vs. moderate' exercise 0 -1 1;
run;
/* slides 24 */
proc glm data=pulse;
class smoker exercise;
model pulse1 = smoker exercise;
run;
/* slides 25 */
proc glm data=pulse;
class smoker exercise;
model pulse1 = smoker exercise smoker*exercise;
run;
/* slides 27 */
proc npar1way data=pulse wilcoxon;
class smoker;
var pulse1;
run;
/* slides 28 */
proc univariate data=pulse;
where ran='Ran';
var PulseDiff;
run;
/* slides 29 */
proc npar1way data=pulse wilcoxon;
class Exercise;
var pulse1;
run;
/* slides 30 */
symbol1 value=plus interpol=r;
proc gplot data = pulse;
plot Pulse1*age;
run;
/* slides 31 */
proc corr data=pulse;
var pulse1 age;
run;
/* slides 33 */
proc gchart data=pulse;
hbar gender;
pie gender;
run;
/* slides 34 */
proc gchart data=pulse;
hbar exercise;
pie exercise;
run;
/* slides 35 */
pattern1 color=red;
pattern2 color=blue;
pattern3 color=green;
proc gchart data=pulse;
vbar smoker / type=percent group=gender patternid=midpoint;
vbar alcohol / type=percent group=gender patternid=midpoint;
vbar exercise / type=percent group=gender patternid=midpoint;
run;
/* slides 36 */
pattern1 color=red;
pattern2 color=blue;
pattern3 color=green;
proc gchart data=pulse;
vbar gender / subgroup=smoker;
vbar gender / subgroup=alcohol;
vbar gender / subgroup=exercise;
run;
/* slides 37 */
proc freq data=pulse;
tables gender smoker alcohol exercise;
run;
/* slides 38 */
proc freq data=pulse;
tables gender * smoker;
run;
/* slides 39 */
proc freq data=pulse;
tables gender * (alcohol exercise);
run;
/* slides 40 */
proc freq data=pulse;
tables gender * smoker / Chisq Fisher;
run;
/* slides 41 */
proc freq data=pulse;
tables gender * (alcohol exercise) / Chisq Fisher;
run;
/* slides 44 */
ODS RTF FILE = "D:\ECUconsultation\SASworkshop\odsoutput1.rtf";
proc means data=pulse;
label Pulse1 = 'First pulse measure';
class smoker;
var pulse1;
run;
ODS RTF CLOSE;
/* slides 45 */
ODS OUTPUT "Summary Statistics"=Stats;
proc means data=pulse;
label Pulse1 = 'First pulse measure';
class smoker;
var pulse1;
run;
ODS OUTPUT CLOSE;
ODS TRACE ON;
proc means data=pulse;
label Pulse1 = 'First pulse measure';
class smoker;
var pulse1;
run;
ODS TRACE OFF;
ODS TRACE ON;
proc glm data=pulse;
class exercise;
model pulse1 = exercise;
run;
ODS TRACE OFF;
