/* Slide 3 */
data market;
input marketid $ cattle cost;
datalines;
A 3.437 27.698
B 12.801 57.634
C 6.136 47.172
D 11.685 49.295
E 5.733 24.115
F 3.021 33.612
G 1.689 9.512
H 2.339 14.755
I 1.025 10.570
J 2.936 15.394
K 5.049 27.843
L 1.693 17.717
M 1.187 20.253
N 9.730 37.465
O 14.325 101.334
P 7.737 47.427
Q 7.538 35.944
R 10.211 45.945
S 8.697 46.890
;
run;
proc print data=market;
run;

/* Slide 4 */
proc gplot data=market;
plot cost*cattle;
run;

/* Slide 5 */
proc corr data=market;
var cattle cost;
run;

/* Slide 7 */
proc reg data=market;
id marketid;
model cost = cattle;
run;

/* Slide 8 */
symbol1 v=plus i=rl;
proc gplot data=market;
plot cost*cattle=1;
run;

/* Slide 9 */
proc reg data=market;
id marketid;
model cost = cattle;
plot residual.*cattle
r.*predicted.
r.*nqq. / mse;
run;

/* Slide 10 */
proc reg data=market;
id marketid;
model cost = cattle / p r clm cli clb influence;
run;

/* Slide 13 */
symbol1 v=plus i=none c=black;
symbol2 v=none i=rlclm95 c=red;
symbol3 v=none i=rlcli95 c=blue;
proc gplot data=market;
plot cost*cattle
cost*cattle
cost*cattle / overlay;
run;

/* Slide 15 */
data auction;
input marketid $ cattle calves hogs sheep cost type $;
volume=cattle+calves+hogs+sheep;
cards;
A 3.437 5.791 3.268 10.649 27.698 O
B 12.801 4.558 5.751 14.375 57.634 O
C 6.136 6.223 15.175 2.811 47.172 O
D 11.685 3.212 .639 .694 49.295 B
E 5.733 3.220 .534 2.052 24.115 B
F 3.021 4.348 .839 2.356 33.612 B
G 1.689 .634 .318 2.209 9.512 O
H 2.339 1.895 .610 .605 14.755 B
I 1.025 .834 .734 2.825 10.570 O
J 2.936 1.419 .331 .231 15.394 B
K 5.049 4.195 1.589 1.957 27.843 B
L 1.693 3.602 .837 1.582 17.717 B
M 1.187 2.679 .459 18.837 20.253 O
N 9.730 3.951 3.780 .524 37.465 B
O 14.325 4.300 10.781 36.863 101.334 O
P 7.737 9.043 1.394 1.524 47.427 B
Q 7.538 4.538 2.565 5.109 35.944 B
R 10.211 4.994 3.081 3.681 45.945 B
S 8.697 3.005 1.378 3.338 46.890 B
;
run;
proc print data=auction;
run;

/* Slide 16 */
proc reg data = auction;
id marketid;
model cost = cattle calves hogs sheep / ss1 ss2;
run;

/* Slide 17 */
proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep/ss1 ss2;
hogs: test hogs=0;
hogsheep: test hogs=0, sheep=0;
intercep: test intercept=0;
hogone: test hogs=1;
hequals: test hogs-sheep=0;
run;

/* Slide 18 */
proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep/ss1 ss2;
restrict intercept=0, hogs-sheep=0;
run;

/* Slide 19 */
proc sgscatter data=auction;
matrix cost cattle calves hogs sheep volume;
run;

/* Slide 20 */
proc corr data= auction;
var cost cattle calves hogs sheep volume;
run;

/* Slide 21 */
proc reg data= auction;
model cost = cattle calves hogs sheep volume;
run;

/* Slide 22 */
proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep / vif;
run;

/* Slides 23 - 25 */
proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep / selection=backward;
run;

proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep / selection=forward;
run;

proc reg data=auction;
id marketid;
model cost=cattle calves hogs sheep / selection=stepwise;
run;

/* Slide 26 */
data cholesterol;
input cholesterol age state $;
datalines;
181 46 Iowa
228 52 Iowa
182 39 Iowa
249 65 Iowa
259 54 Iowa
201 33 Iowa
121 49 Iowa
339 76 Iowa
224 71 Iowa
112 41 Iowa
189 58 Iowa
137 18 Nebraska
173 44 Nebraska
177 33 Nebraska
241 78 Nebraska
225 51 Nebraska
223 43 Nebraska
190 44 Nebraska
257 58 Nebraska
337 63 Nebraska
189 19 Nebraska
214 42 Nebraska
140 30 Nebraska
196 47 Nebraska
262 58 Nebraska
261 70 Nebraska
356 67 Nebraska
159 31 Nebraska
191 21 Nebraska
197 56 Nebraska
;
run;

symbol1 v=square i=rl c=red;
symbol2 v=triangle i=rl c=blue;
proc gplot data=cholesterol;
plot cholesterol*age=state;
run;

/* Slide 27 */
proc glm data = cholesterol;
class state;
model cholesterol = age state age*state / solution;
run;

/* Slide 29 */
proc glm data = cholesterol;
class state;
model cholesterol = age state / solution;
run;

/* Slide 30 */
proc glm data = cholesterol;
class state;
model cholesterol = age state age*state;
lsmeans state;
estimate 'Iowa at 60 years old' intercept 1 state 1 0 age 60;
contrast 'Iowa vs. Nebraska at 60 years old' intercept 0 state 1 -1 age 60;
run;